mirror of
https://github.com/pezkuwichain/pezkuwi-subxt.git
synced 2026-05-08 10:08:02 +00:00
Alexander Theißen
04b185e3d4
* seal: Change prefix "ext_" to "seal_" for contract callable functions The word Ext is a overloaded term in the context of substrate. It usually is a trait which abstracts away access to external resources usually in order to mock them away for the purpose of tests. The contract module has its own `Ext` trait in addition the the substrate `Ext` which makes things even more confusing. In order to differentiate the contract callable functions more clearly from this `Ext` concept we rename them to use the "seal_" prefix instead. This should change no behaviour at all. This is a pure renaming commit. * seal: Rename import module from "env" to "seal0" * seal: Fixup integration test * seal: Add more tests for new import module names
81 lines
2.3 KiB
WebAssembly Text Format
81 lines
2.3 KiB
WebAssembly Text Format
(module
|
|
(import "seal0" "seal_input" (func $seal_input (param i32 i32)))
|
|
(import "seal0" "seal_address" (func $seal_address (param i32 i32)))
|
|
(import "seal0" "seal_call" (func $seal_call (param i32 i32 i64 i32 i32 i32 i32 i32 i32) (result i32)))
|
|
(import "seal0" "seal_terminate" (func $seal_terminate (param i32 i32)))
|
|
(import "env" "memory" (memory 1 1))
|
|
|
|
;; [0, 8) reserved for $seal_address output
|
|
|
|
;; [8, 16) length of the buffer
|
|
(data (i32.const 8) "\08")
|
|
|
|
;; [16, 24) Address of django
|
|
(data (i32.const 16) "\04\00\00\00\00\00\00\00")
|
|
|
|
;; [24, 32) reserved for output of $seal_input
|
|
|
|
;; [32, 36) length of the buffer
|
|
(data (i32.const 32) "\04")
|
|
|
|
;; [36, inf) zero initialized
|
|
|
|
(func $assert (param i32)
|
|
(block $ok
|
|
(br_if $ok
|
|
(get_local 0)
|
|
)
|
|
(unreachable)
|
|
)
|
|
)
|
|
|
|
(func (export "deploy"))
|
|
|
|
(func (export "call")
|
|
;; If the input data is not empty, then recursively call self with empty input data.
|
|
;; This should trap instead of self-destructing since a contract cannot be removed live in
|
|
;; the execution stack cannot be removed. If the recursive call traps, then trap here as
|
|
;; well.
|
|
(call $seal_input (i32.const 24) (i32.const 32))
|
|
(if (i32.load (i32.const 32))
|
|
(then
|
|
(call $seal_address (i32.const 0) (i32.const 8))
|
|
|
|
;; Expect address to be 8 bytes.
|
|
(call $assert
|
|
(i32.eq
|
|
(i32.load (i32.const 8))
|
|
(i32.const 8)
|
|
)
|
|
)
|
|
|
|
;; Recursively call self with empty input data.
|
|
(call $assert
|
|
(i32.eq
|
|
(call $seal_call
|
|
(i32.const 0) ;; Pointer to own address
|
|
(i32.const 8) ;; Length of own address
|
|
(i64.const 0) ;; How much gas to devote for the execution. 0 = all.
|
|
(i32.const 36) ;; Pointer to the buffer with value to transfer
|
|
(i32.const 8) ;; Length of the buffer with value to transfer
|
|
(i32.const 0) ;; Pointer to input data buffer address
|
|
(i32.const 0) ;; Length of input data buffer
|
|
(i32.const 4294967295) ;; u32 max sentinel value: do not copy output
|
|
(i32.const 0) ;; Length is ignored in this case
|
|
)
|
|
(i32.const 0)
|
|
)
|
|
)
|
|
)
|
|
(else
|
|
;; Try to terminate and give balance to django.
|
|
(call $seal_terminate
|
|
(i32.const 16) ;; Pointer to beneficiary address
|
|
(i32.const 8) ;; Length of beneficiary address
|
|
)
|
|
(unreachable) ;; seal_terminate never returns
|
|
)
|
|
)
|
|
)
|
|
)
|